root/simulator/trunk/src/utilities/pathbuilder/CMakeLists.txt

#    OSRail -- a network enabled railroad operations simulator and utilities
#    Copyright (C) 2007,2008,2009 Samuel E. Henley sehenley@comcast.net
#
#    This program is free software; you can redistribute it and/or modify
#    it under the terms of the GNU General Public License as published by
#    the Free Software Foundation; either version 2 of the License, or
#    (at your option) any later version.
#
#    This program is distributed in the hope that it will be useful,
#    but WITHOUT ANY WARRANTY; without even the implied warranty of
#    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
#    GNU General Public License for more details.
#
#    You should have received a copy of the GNU General Public License along
#    with this program; if not, write to the Free Software Foundation, Inc.,
#    51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
#
#
#----------------------------------------------------------------------
## \file
## \page pathbuildercmakelists PathBuilder CMakeLists.txt File.
## This is the cmakelist.txt build file for the \ref PathBuilder.
## The \ref prerequisite.cmake file checks for ogre, OIS
## and wxwidgets software development kits. \ref PathBuilder
## will allow the user to plot the track paths. It will allow the user
## to reconcile both digital and scanned maps, and scanned track
## profiles. Pathbuilder will create an xml output representing a
## track path. The xml file will include the user's notes and
## source data references and other properties for the RouteBuilder.
## The script will also build PathbuilderXRCResources.
#----------------------------------------------------------------------

# This project can be built independently
PROJECT( PathBuilder CXX )
CMAKE_MINIMUM_REQUIRED( VERSION 2.6.3 )

# Get Working Directory trunk tag branch
IF( NOT SIMULATOR_WORKING_DIRECTORY )
    STRING( REGEX REPLACE "/src/utilities/pathbuilder$" ""
        SIMULATOR_WORKING_DIRECTORY
        ${TrainGear_SOURCE_DIR}
    )

    FIND_PATH( SIMULATOR_WORKING_DIRECTORY
            Modules/prerequisite.cmake
            ${SIMULATOR_WORKING_DIRECTORY}
            DOC "The working directory is trunk, or a tag or a branch name."
    )

    STRING( REGEX REPLACE "/utilities/pathbuilder$" "/bin"
        SIMULATOR_WORKING_BINARY_DIRECTORY
        ${PathBuilder_BINARY_DIR}
    )

    INCLUDE( ${SIMULATOR_WORKING_DIRECTORY}/Modules/prerequisite.cmake )

ENDIF( NOT SIMULATOR_WORKING_DIRECTORY )


## \remarks
## Prebuild step for vc produces pathbuilderresources.cpp
## Custom command for pre-build event must be done after target (pathbuilder) is added
## There is no pre-build event for msvc 6.0
## CommandLine=wxrc -g pathbuilder.xrc --uncompressed --cpp-code --output pathbuilderresources.cpp


SET( RESOURCE_SOURCES
     ${PROJECT_SOURCE_DIR}/pathbuilder.xrc
)

ADD_CUSTOM_COMMAND(  OUTPUT ${PROJECT_BINARY_DIR}/pathbuilderresources.cpp
                     COMMAND ${OSRAILWXWIDGETS_WXRC_EXECUTABLE}
                     ARGS --cpp-code ${RESOURCE_SOURCES}
                          --output=${PROJECT_BINARY_DIR}/pathbuilderresources.cpp
                     DEPENDS ${RESOURCE_SOURCES}
                     WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}
                     COMMENT "Build pathbuilderresources.cpp"
)

SET_DIRECTORY_PROPERTIES( PROPERTIES
                          ADDITIONAL_MAKE_CLEAN_FILES ${PROJECT_BINARY_DIR}/pathbuilderresources.cpp
)

## \note Global/Director/Target  property CODEBLOCKS_CONFIGURED_FILES = is a list
## of files  that are the source for a generated source file or script - this is a clue
## to programmer not to edit a generate${CMAKE_CURRENT_SOURCE_DIR} file but edit it's source and re-configure.
## Files are cumulative from global, directory to target.

SET_PROPERTY( DIRECTORY ${PROJECT_SOURCE_DIR}
              PROPERTY CODEBLOCKS_GENERATED_FILES ${PROJECT_BINARY_DIR}/pathbuilderresources.cpp
)

SET( PCH_HEADER prepathbuilder.h )

SET( HEADERS
    ${PCH_HEADER}
    pathbuilder.h
    pathlistframe.h
    pathdrgframe.h
    pathimageframe.h
    pathdoqqframe.h
    pathned2dframe.h
    pathned3dframe.h
    pathdocument.h
    pathlistview.h
    pathtreeview.h
    pathcanvas.h
    path3dcanvas.h
)

SET( SOURCES
    pathbuilder.cpp
    pathlistframe.cpp
    pathdrgframe.cpp
    pathimageframe.cpp
    pathdoqqframe.cpp
    pathned2dframe.cpp
    pathned3dframe.cpp
    pathdocument.cpp
    pathlistview.cpp
    pathtreeview.cpp
    pathcanvas.cpp
    path3dcanvas.cpp
)

# The Build is divided into source and binary paths
SET( PATHBUILDER_SOURCES
     ${PCH_DUMMY}
     ${SOURCES}
     ${HEADERS}
)

SOURCE_GROUP( "Source Files"
    FILES ${SOURCES}
)

SOURCE_GROUP( "Header Files"
    FILES ${HEADERS}
)

SOURCE_GROUP( "Pre-Compiled Header"
    FILES ${PCH_HEADER}
    ${PCH_DUMMY}
)

# WIN32 has no effect on any system other than Windows -
# on Windows uses WinMain rather then main.
ADD_EXECUTABLE( PathBuilder WIN32
    ${PATHBUILDER_SOURCES}
)

PACKAGE_CONFIGURE( PathBuilder
                  Debug wx-config ${WXPREFIX} ${WXCFG_DEBUG} --unicode=no --debug=yes --static=no --cflags
                  debug wx-config ${WXPREFIX} ${WXCFG_DEBUG} --unicode=no --debug=yes --static=no --libs
                  RelWithDebInfo Release MinSizeRel wx-config ${WXPREFIX} ${WXCFG} --unicode=no --debug=no --static=no --cflags
                  optimized wx-config ${WXPREFIX} ${WXCFG} --unicode=no --debug=no --static=no --libs
                  paths.pc
                  boost.pc
                  ipc.pc
                  launcher.pc
                  angelscript.pc
                  gdalogr.pc
                  mststokens.pc
                  gdalutilities.pc
                  location.pc
                  nationalgrid.pc
                  scriptmanager.pc
                  ogrewindowmanager.pc
                  gtk+-2.0
                  curl.pc
                  processor.pc
                  OGRE.pc
                  OIS.pc
                  osrail.pc
)

ADD_LIBRARY( pathbuilderxrcresources STATIC
    ${PROJECT_BINARY_DIR}/pathbuilderresources.cpp
)

PACKAGE_CONFIGURE( pathbuilderxrcresources
                  Debug wx-config ${WXPREFIX} ${WXCFG_DEBUG} --unicode=no --debug=yes --static=no --cflags
                  RelWithDebInfo Release MinSizeRel wx-config ${WXPREFIX} ${WXCFG} --unicode=no --debug=no --static=no --cflags
                  osrail.pc
)

TARGET_LINK_LIBRARIES( PathBuilder
    optimized pathbuilderxrcresources
    debug pathbuilderxrcresources_d
)


PRECOMPILED_HEADER( "Unix Makefiles" PathBuilder ${PCH_HEADER} ${SIMULATOR_WORKING_INCLUDE_DIRECTORY} )
PRECOMPILED_HEADER( "CodeBlocks" PathBuilder ${PCH_HEADER} "1" )
PRECOMPILED_HEADER( "MinGW Makefiles" PathBuilder ${PCH_HEADER} ${SIMULATOR_WORKING_INCLUDE_DIRECTORY} )

ADD_DEPENDENCIES( PathBuilder
    pathbuilderxrcresources
    nationalgrid
    ipc
    launcher
    gdalutilities
    ogrewindowmanager
    scriptmanager
)

## \par Win32 Resource
## Resource required for application icon on windows.
## Resource are a custom command because the vc ide world leave
## unwanted binary files in the source tree if the rc file is
## added to the project source. The resulting res file is named as a library file
## so that it will go into TARGET_LINK_LIBRARIES without a name change.
## RC can figure out that it's really a resource file or maybe it really is a library?

IF( WIN32 )

    ADD_CUSTOM_COMMAND( TARGET PathBuilder
                        PRE_BUILD
                        COMMAND ${RC_EXECUTABLE}
                        ARGS -fo${SIMULATOR_WORKING_ARCHIVE_DIRECTORY}/libpathbuilderwin32resources.a
                             ${PROJECT_SOURCE_DIR}/pathbuilder.rc
                        MAIN_DEPENDENCY ${PROJECT_SOURCE_DIR}/pathbuilder.rc
                        COMMENT "Windows Application Icon"
    )

    TARGET_LINK_LIBRARIES( PathBuilder
                           pathbuilderwin32resources
    )

    INCLUDE_DIRECTORIES( ${PROJECT_SOURCE_DIR} )

ENDIF( WIN32 )

## \par Subdirectories Scripts.
## installer test
## The installer is a part of the build and integration test
## The installer has its own unit tests. The test sub-directory is the
## unit tests for PathBuilder.
SUBDIRS( test )