root/simulator/trunk/src/internationalization/i18n.cmd

echo off
rem    traingear -- a network enabled railroad operations simulator and utilities
rem    Copyright (C) 2007,2008 Samuel E. Henley sehenley@comcast.net
rem 
rem    This program is free software; you can redistribute it and/or modify
rem    it under the terms of the GNU General Public License as published by
rem    the Free Software Foundation; either version 2 of the License, or
rem    (at your option) any later version.
rem
rem    This program is distributed in the hope that it will be useful,
rem    but WITHOUT ANY WARRANTY; without even the implied warranty of
rem    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
rem    GNU General Public License for more details.
rem
rem    You should have received a copy of the GNU General Public License along
rem    with this program; if not, write to the Free Software Foundation, Inc.,
rem    51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
rem
rem

rem @ \file
rem @ Builds the mo files for internationalzation and update source po files.
rem @ \note arguments %1=${SIMULATOR_WORKING_BINARY_DIRECTORY}
rem @                 %2=${GNU_XGETTEXT_UTILITY}
rem @                 %3=${WXWINDOWS_WXRC_UTILITY}
rem @                 %4=${SIMULATOR_WORKING_DIRECTORY}
rem @


rem @ \page internationalization1 Internationalization
rem @ \par Internationalization.
rem @ \note The simulator and utilities will use the GNU gettext library to do localization
rem @ and internationalization for both windows and linux. The primary
rem @ tool used will be poEdit. The build process will contain a job (INTERNATIONALIZATION)
rem @ that will gather strings and add then to the source files in the internationalization
rem @ sub-directory of src (trunk/src/internationalization).
rem @ This file is a combination of wxstd.po and the strings gathered from the utilities.
rem @ This po source will install on the user machine with instruction to
rem @ get poEdit to facilitate translations.
rem @


setlocal enabledelayedexpansion

if exist %1\internationalization\tmp (
    rd /s /q %1\internationalization\tmp
)

md %1\internationalization\tmp
cd %1\internationalization\tmp

type nul > cppfiles.txt

rem @ \note Collect xrc files and produce fake cpp files for xgettext.
rem @

for /R %4\src %%F in (*.xrc) do (
    %3 --gettext --cpp-code --output=%1\internationalization\tmp\%%~nFstring.cpp %%F
    echo %1\internationalization\tmp\%%~nFstring.cpp >> cppfiles.txt 
)

rem @ \note Collect all cpp files for xgettext.
rem @
for /R %4\src %%F in (*.cpp) do echo %%F >> cppfiles.txt
for /R %4\src %%F in (*.h) do echo %%F >> cppfiles.txt

rem @ \note Collect all the strings from cpp files using xgettext.
rem @
%2\xgettext.exe --files-from=cppfiles.txt --directory= --c++ --keyword=_ --output=%1\internationalization\tmp\osrail.pot

rem @ \note Collect the current source po files and mearge them with the found strings.
rem @
rem @ \note Move the po files back, po files in the src are the place
rem @ to make changes and translations.
rem @
rem @ \note Create a mo file for each po file, these files are discardable
rem @

for /R %4\src %%F in (??.po) do (
    %2\msgcat.exe --use-first --output=%1\internationalization\tmp\%%~nF.po %%F osrail.pot
    copy /y %1\internationalization\tmp\%%~nF.po %%~pF
    if not exist %1\%%~nF (
       md %1\%%~nF
    )
    %2\msgfmt.exe --output-file=%1\%%~nF\%%~nF.mo %1\internationalization\tmp\%%~nF.po
)

cd ..

rd /s /q %1\internationalization\tmp